Вопросы по скриптам

Автор Potatoider, окт 01 2015 22:45

papyrus help скрипты вопросы

Авторизуйтесь для ответа в теме

#361 Potatoider

Знаменитый оратор
4 350 сообщений

Отправлено 01 октября 2015 - 22:45

Тема для вопросов по скриптингу.

Функции папируса:

На английском

На русском (не все, но базис)

werr, Chesh¡re и Olechkafum нравится это

Наверх

Авторизуйтесь для ответа в теме

Сообщений в теме: 832

#362 mr Jyggalag

Ветеран
609 сообщений

Отправлено 06 июня 2018 - 21:35

Пытаюсь сделать скрипт, что по внутреннему таймеру "менял" бы письма на определённом столике. Сделать смену писем было легко, но прикрутить таймер к скрипту для меня оказалось довольно сложно... Вроде бы этот скрипт работает при компиляции, но когда я жду отведённый срок (4 дня) игра вылетает. Вопрос следующий - кто знает, как правильно "таймеры" делать?

Сам скрипт:

Scriptname NiranyesLetters extends ObjectReference  

GlobalVariable Property DaysForUpdateLetter  Auto
GlobalVariable Property TimeBeforeUpdateLetter  Auto 
ObjectReference Property Letter00  Auto  
ObjectReference Property Letter01  Auto  
ObjectReference Property Letter02  Auto  
ObjectReference Property Letter03  Auto  
ObjectReference Property Letter04  Auto  
ObjectReference Property Letter05  Auto  

Event OnTriggerEnter(ObjectReference akActionRef)
    If TimeBeforeUpdateLetter.Getvalue() == 0
        TimeBeforeUpdateLetter.SetValue(DaysForUpdateLetter.GetValueInt())
        RegisterForUpdateGameTime(24.0)
    EndIf
EndEvent

Event OnUpdateGameTime()
    If TimeBeforeUpdateLetter.Getvalue() != 0
        If (TimeBeforeUpdateLetter.GetValueInt() - 1)<=0
            TimeBeforeUpdateLetter.SetValue(0)
            LetterUpdate()
        Else
            TimeBeforeUpdateLetter.SetValue(TimeBeforeUpdateLetter.GetValueInt() - 1)
        EndIf
    Endif
EndEvent

Function LetterUpdate()
    DisableLettersN()
    int RandomNum = Utility.RandomInt(1, 60)
    If (1 <= RandomNum) && (RandomNum <= 10)
            Letter00.Enable()
    ElseIf (11 <= RandomNum) && (RandomNum <= 20)
            Letter01.Enable()
    ElseIf (21 <= RandomNum) && (RandomNum <= 30)
            Letter02.Enable()
    ElseIf (31 <= RandomNum) && (RandomNum <= 40)
            Letter03.Enable()
    ElseIf (41 <= RandomNum) && (RandomNum <= 50)
            Letter04.Enable()
    ElseIf (51 <= RandomNum) && (RandomNum <= 60)
            Letter05.Enable()
    EndIf
EndFunction

Function DisableLettersN()
    Letter00.Disable()
    Letter01.Disable()
    Letter02.Disable()
    Letter03.Disable()
    Letter04.Disable()
    Letter05.Disable()
EndFunction

DaysForUpdateLetter равно 4
TimeBeforeUpdateLetter изначально равно нулю

Наверх

#363 Azazellz

Знаменитый оратор
2 055 сообщений

Отправлено 06 июня 2018 - 22:10

Чота у тебя регистрация и "он апдейт" к триггеру чтоль привязаны? А анрегистер где?

Так нельзя же делать.

Пили лучше квест.

Зашел в триггер - включился квест стадии 10, стартовал отсчет (и триггер отключился заодно). После отсчета появилось письмо, заодно сам отсчет отключился.

Игрок прочитал записку - включился квест стадии 20, пошел новый отсчет.

Ну и т.д.

Последнюю записку прочел - квест остановился. Это автоматически сделает анрегистр всем апдейтам.

Сообщение отредактировал Azazellz: 06 июня 2018 - 22:15

Наверх

#364 mr Jyggalag

Ветеран
609 сообщений

Отправлено 07 июня 2018 - 09:36

Чота у тебя регистрация и "он апдейт" к триггеру чтоль привязаны? А анрегистер где?
Так нельзя же делать.

Пили лучше квест.
Зашел в триггер - включился квест стадии 10, стартовал отсчет (и триггер отключился заодно). После отсчета появилось письмо, заодно сам отсчет отключился.
Игрок прочитал записку - включился квест стадии 20, пошел новый отсчет.
Ну и т.д.
Последнюю записку прочел - квест остановился. Это автоматически сделает анрегистр всем апдейтам.

Проблема заключается в том, что мне как раз и не надо, чтобы игрок читал письма - они бы случайно просто переиздавались бы, без участия игрока. Я пока решил послать нафиг эти манипуляции с от счётом времени и воспользоваться таймером, сделанным на основе магического эффекта (с выставленным мною временем).

Наверх

#365 Azazellz

Знаменитый оратор
2 055 сообщений

Отправлено 07 июня 2018 - 10:02

Ну так если тебе "случайно" надо - так и сделай случайно, без таймера.

Подошел игрок к письмам, зацепил триггер - и он одно из писем рандомно "включил".

Подошел еще раз - включил другое (или то же самое).

Но с магэффектом тоже неплохая идея, да.

Наверх

#366 mfloengrin

Новенький
11 сообщений

Отправлено 29 июня 2018 - 17:18

Добрый день! Подскажите пожалуйста что нужно прописать в скрипте диалога чтобы после его завершения открывалось рэйс меню , а после его закрытия стадия квэста считалась завершенной.

Наверх

#367 Azazellz

Знаменитый оратор
2 055 сообщений

Отправлено 29 июня 2018 - 18:11

https://www.creation...RaceMenu_-_Game

Насчет второго - даже хз.

По идее если ты открыл рейсменю - ты его должен когда-то закрыть, ибо выхода то оттуда никакого другого нет. При этом пока оно открыто - время самой игры стоит.

Поэтому можно попробовать использовать какой-нибудь таймер, ну или заюзать функцию wait (эту или эту).

Т.е. скриптом открываешь рейсменю, кодируешь небольшое ожидание, и после этого ожидания переключаешь стадию квеста.

Наверх

#368 mfloengrin

Новенький
11 сообщений

Отправлено 29 июня 2018 - 20:28

https://www.creation...RaceMenu_-_Game

Насчет второго - даже хз.

По идее если ты открыл рейсменю - ты его должен когда-то закрыть, ибо выхода то оттуда никакого другого нет. При этом пока оно открыто - время самой игры стоит.

Поэтому можно попробовать использовать какой-нибудь таймер, ну или заюзать функцию wait (эту или эту).

Т.е. скриптом открываешь рейсменю, кодируешь небольшое ожидание, и после этого ожидания переключаешь стадию квеста.

Спасибо большое

Наверх

#369 werr

больной на всю голову
1 733 сообщений

Отправлено 30 июня 2018 - 12:42

Добрый день! Подскажите пожалуйста что нужно прописать в скрипте диалога чтобы после его завершения открывалось рэйс меню , а после его закрытия стадия квэста считалась завершенной.

Если говорить про аккуратную реализацию того, что ты хочешь, для этого требуется SKSE.

В скрипте диалога-то ты прописываешь простую команду:

Game.ShowRaceMenu()

А смена стадии квеста при выходе из этого меню делается чуть мудренее. Вешаешь новый скрипт на квест, где будет следуюющее:

Event OnInIt()
    RegisterForMenu("RaceSex Menu")
EndEvent

Event OnMenuClose(String MName)
    If MName == "RaceSex Menu"
        SetStage(xx)
        UnregisterForAllMenus()
    Endif
EndEvent

A Random Dude's Story

Наверх

#370 mfloengrin

Новенький
11 сообщений

Отправлено 30 июня 2018 - 23:16

Если говорить про аккуратную реализацию того, что ты хочешь, для этого требуется SKSE.

В скрипте диалога-то ты прописываешь простую команду:
Game.ShowRaceMenu()
А смена стадии квеста при выходе из этого меню делается чуть мудренее. Вешаешь новый скрипт на квест, где будет следуюющее:
Event OnInIt()
    RegisterForMenu("RaceSex Menu")
EndEvent

Event OnMenuClose(String MName)
    If MName == "RaceSex Menu"
        SetStage(xx)
        UnregisterForAllMenus()
    Endif
EndEvent

Спасибо большое))

Наверх

#371 allgamer955

Новенький
6 сообщений

Отправлено 05 июля 2018 - 16:36

Уважаемые форумчане, подскажите пожалуйста почему не работает такой скрипт?

Scriptname ADoTeleportHouseScript extends ActiveMagicEffect
Bool  bHouse = False
Event OnEffectFinish(Actor akTarget, Actor akCaster)
If  bHouse ; True
  Debug.MessageBox(bHouse)
Else ; False
  Debug.MessageBox(bHouse)
Endif
bpHouse = !bpHouseendEVENT

Сколько бы ни кастовал, всё время пишет False.

Наверх

#372 werr

больной на всю голову
1 733 сообщений

Отправлено 05 июля 2018 - 23:40

Уважаемые форумчане, подскажите пожалуйста почему не работает такой скрипт?
Scriptname ADoTeleportHouseScript extends ActiveMagicEffectBool  bHouse = FalseEvent OnEffectFinish(Actor akTarget, Actor akCaster)If  bHouse ; True  Debug.MessageBox(bHouse)Else ; False  Debug.MessageBox(bHouse)EndifbpHouse = !bpHouseendEVENT
Сколько бы ни кастовал, всё время пишет False.

А что еще он должен писать? У тебя bHouse всегда False. Ты значение не меняешь.

P.s. bpHouse и bpHouseendEVENT не определены. Такой скрипт даже компилироваться не будет. Ты как будто только кусок кода скинул.

A Random Dude's Story

Наверх

#373 allgamer955

Новенький
6 сообщений

Отправлено 06 июля 2018 - 08:46

Вы правы, ошибка в тексте вопроса.

Чтобы исправить ошибки задам вопрос заново

Почему скрипт прикреплённый к триггеру

Scriptname a0DoLightScript extends ObjectReference  

Bool  bHouse = False

Event OnTriggerEnter(ObjectReference akActionRef)
	if akActionRef == Game.GetPlayer()
		If  bHouse ; True
		Debug.MessageBox(bHouse)
		Else ; False
		Debug.MessageBox(bHouse)
		Endif
		bHouse = !bHouse 
	endif
EndEvent

работает корректно, а скрипт прикреплённый к заклинанию

Scriptname ADoTeleportHouseScript extends ActiveMagicEffect  

Bool  bHouse = False

Event OnEffectFinish(Actor akTarget, Actor akCaster)
	If  bHouse ; True
		Debug.MessageBox(bHouse)   ; Будет скрипт телепортации в дом.
	Else ; False
		Debug.MessageBox(bHouse)   ; Будет скрипт телепортации из дома.
	Endif
	bHouse = !bHouse 

endEVENT

работает не корректно. Всё время пишет "Fflse"

Переменная сохраняется только во время выполнения скрипта.

Наверх

#374 Azazellz

Знаменитый оратор
2 055 сообщений

Отправлено 06 июля 2018 - 08:47

P.s. bpHouse и bpHouseendEVENT не определены.

Я так думаю, что это "bpHouse = !bpHouse" и "endEVENT"
Перевод строки потерялся =)

Наверх

#375 werr

больной на всю голову
1 733 сообщений

Отправлено 06 июля 2018 - 11:04

Вы правы, ошибка в тексте вопроса.
Чтобы исправить ошибки задам вопрос заново

Почему скрипт прикреплённый к триггеру
...
работает корректно, а скрипт прикреплённый к заклинанию
...
работает не корректно. Всё время пишет "Fаlse"

Ага, понятно. Дело в том, что инстанция (instance) скрипта, что срабатывает на триггере, не меняется. Проще говоря – работает ВСЕГДА один и тот же скрипт.

В случае же магического эффекта, он, этот эффект, привязан к заклинанию. Каждый раз, когда кастуется спелл, на ActiveMagicEffect-е рабочая instance твоего скрипта инициализируется по-новой. Потому как формально, всякий раз при кастовании спелл возникает как новый объект. Говоря иначе, при касте заклинания, скрипт стартует с самого начала, каждый раз как первый раз. А поскольку исходное значение тобой задано как FALSE, то в if и срабатывает соответствующая ветка.

Совет может быть таким. Если тебе хочется использовать ActiveMagicEffect, то имеет смысл завести глобальную переменную вместо локальной для данного скрипта и работать с ней.

Я так думаю, что это "bpHouse = !bpHouse" и "endEVENT"
Перевод строки потерялся =)

Это я чето в два ночи не сообразил))

A Random Dude's Story

Наверх

#376 allgamer955

Новенький
6 сообщений

Отправлено 06 июля 2018 - 17:10

Если тебе хочется использовать ActiveMagicEffect,....

Какие могут быть варианты? Не предлагать двери и вещи.

то имеет смысл завести глобальную переменную вместо локальной для данного скрипта и работать с ней.

С глобальной переменной начинает получатся. Спасибо.

Наверх

#377 allgamer955

Новенький
6 сообщений

Отправлено 06 июля 2018 - 20:15

Вот что получилось со скриптом заклинания телепортации.

Scriptname aDoTeleportScript extends activemagiceffect  

GlobalVariable Property gpHouse  Auto 
ObjectReference Property PalaseDova  Auto  
ObjectReference Property WorldDova  Auto  

Event OnEffectStart(Actor akTarget, Actor akCaster)
	If  gpHouse.GetValue() == 0 ; True
;		Debug.MessageBox(gpHouse.GetValue())   ; Телепортация в дом.
		gpHouse.SetValue(1)
		WorldDova.MoveTo(Game.GetPlayer())
		Game.GetPlayer().MoveTo( PalaseDova)
	Else ; False
;		Debug.MessageBox(gpHouse.GetValue())   ; Телепортация из дома.
		gpHouse.SetValue(0)
		Game.GetPlayer().MoveTo( WorldDova)
	Endif

EndEvent

Скрипт прекрасно работает.

Ещё бы заставить напарника телепортировался. Как это можно сделать?

Кто знает подскажите пожалуйста

Наверх

#378 Azazellz

Знаменитый оратор
2 055 сообщений

Отправлено 06 июля 2018 - 21:33

Напарник, по идее, сам переместиться должен - если в доме навмеши проложены, и если у него АИ-пакет на следование за игроком прописан.

Наверх

#379 allgamer955

Новенький
6 сообщений

Отправлено 06 июля 2018 - 22:07

Навмеши есть. Фендел Не хочет телепортироваться.

В двери идет, телепортироваться не хочет.

Наверх

#380 Azazellz

Знаменитый оратор
2 055 сообщений

Отправлено 06 июля 2018 - 22:40

Ну тут уж хз. Когда я телепорты из Mark and Recall юзал - фолловеры за мной бегали. Может, не сразу, с небольшими задержками, но бегали.

Главная трудность, имхо - определить, кто там сейчас в КуррентФолловерах находится.

Можешь попробовать разобрать спелл "Лидерская Телепортация" из EFF. При использовании этот спелл перемещает к игроку всех активных фолловеров. Только вот в EFF своя система спутников, и я хз, как она устроена - ни разу в нее не лазил. Да и в ванильную тоже довольно поверхностно - если сможешь найти, куда там текущий спутник записывается (в аллиас квестовый какой-нибудь, например) то можно будет его оттуда и брать, а потом уже moveto на него использовать.

Сообщение отредактировал Azazellz: 06 июля 2018 - 22:41

Наверх

#381 mr Jyggalag

Ветеран
609 сообщений

Отправлено 08 июля 2018 - 10:11

Можно попробовать использовать в скрипте

Game.FastTravel(HomeMarker)

где HomeMarker это маркер, к которому будет телепортироваться игрок

Это принудительный фасттревел, так что, по идее, компаньоны и КО (призванные существа там всякие, компаньоны-животные, etc) должны повести себя стандартно, т.е телепортироваться вместе с игроком.
Единственное "но" - я не помню, получится ли так телепортировать игрока в локацию, в настройках которой запрещена возможность фасттревела.

Наверх

Темы с аналогичным тегами papyrus, help, скрипты, вопросы

Моддинг → Моддинг Skyrim → Восстановление на основе Зала Дозора Автор Alex_andra, 11 дек 2023 mod, help	4 Ответов 435 Просмотров	Alex_andra 13 дек 2023
Моддинг → Моддинг Skyrim → Отстройка Винтерхолда Автор Alex_andra, 10 авг 2023 bugs, moding, help	5 Ответов 442 Просмотров	Azazellz 20 авг 2023
Моддинг → Моддинг Oblivion → Скрипт Для Снаряжения Автор БесездаБойчик, 07 сен 2022 скрипты, скрипт	9 Ответов 599 Просмотров	Pimple03 08 сен 2022
Моддинг → Моддинг Skyrim → Нужны добровольцы для теста мода Автор arkadiy111, 11 апр 2022 help	2 Ответов 2 130 Просмотров	arkadiy111 12 апр 2022
help Моддинг → Моддинг Skyrim → Ram and Skyrim se Автор Samurai1, 03 апр 2022 help	0 Ответов 1 939 Просмотров	Samurai1 03 апр 2022

Количество пользователей, читающих эту тему: 2

0 пользователей, 1 гостей, 0 скрытых

Bing (1)